Como ler Dados de Verificação de 30 MHz a 1 GHz?
Resposta
O seguinte programa define uma verificação de 30 MHz a 1 GHz, inicia e escreve todos os dados verificados em um arquivo.
10 IEC TERM 10
20 IEC TIME 5000
25 REM Os dados verificados serão armazenados no arquivo 'DATA.DAT'
30 OPENO# 1,"DATA.DAT"
35 REM A verificação é definida das linhas 40 a 200
40 IEC OUT 21,"*RST;*CLS;*OPC"
50 IEC OUT 21,"INSTRUMENT RECEIVER"
60 IEC OUT 21,"SCAN:RANGES 1"
70 IEC OUT 21,"FREQUENCY:START 30MHZ"
80 IEC OUT 21,"FREQUENCY:STOP 1GHZ"
90 IEC OUT 21,"DISPLAY:TRACE:Y:TOP 100"
100 IEC OUT 21,"DISPLAY:TRACE:Y:BOTTOM -20"
110 IEC OUT 21,"SWEEP:SPACING LINEAR"
120 IEC OUT 21,"DETECTOR:RECEIVER POSITIVE,AVERAGE"
130 IEC OUT 21,"SCAN1:START 30MHZ"
140 IEC OUT 21,"SCAN1:STOP 1GHZ"
150 IEC OUT 21,"SCAN1:STEP 50KHZ"
160 IEC OUT 21,"SCAN1:BANDWIDTH:RESOLUTION 120KHZ"
170 IEC OUT 21,"SCAN1:TIME 1MS"
180 IEC OUT 21,"SCAN1:INPUT:TYPE INPUT2"
190 IEC OUT 21,"SCAN1:INPUT:ATTENUATION:AUTO ON"
200 IEC OUT 21,"SCAN1:INPUT:GAIN:AUTO ON"
203 IEC OUT 21,"DISPLAY:FORMAT SINGLE"
205 REM Temos que configurar o formato de transferência para real 32
210 IEC OUT 21,"FORMAT REAL,32"
220 IEC OUT 21,"*CLS"
225 REM Habilitamos a transferência de dados de verificação enquanto a verificação está em execução
230 IEC OUT 21,"TRACE:FEED:CONTROL ALWAYS"
235 REM A verificação é iniciada como uma única verificação
240 IEC OUT 21,"INITIATE2:CONTINUOUS OFF;*OPC"
250 IEC OUT 21,"INITIATE2:IMMEDIATE"
260 REPEAT
270 REPEAT
275 REM O bit 9 do STATUS:OPERATION:CONDITION é definido quando os dados de verificação
276 REM estiverem disponíveis
280 IEC OUT 21,"STATUS:OPERATION:CONDITION?"
290 IEC IN 21,S$
300 UNTIL S$="512"
305 REM Obtemos um bloco de verificação e o armazenamos em 'DATA.DAT'
310 IEC OUT 21,"TRACE? SCAN"
320 IEC IN 21,T$
330 PRINT# 1,T$
333 REM O bloco de verificação tem um cabeçalho. O primeiro caractere é #. O segundo
334 REM caractere indica o número de bytes que virão com informação
335 REM adicional, ex. 2. A informação adicional indica o número
336 REM de bytes que virão com dados de verificação: ex 32.
340 A=VAL(MID$(T$,2,1))+4
345 REM Nós repetiremos a linha de loop 260 até que o bit 12 do bloco de verificação
346 REM (sem cabeçalho) esteja configurado.
350 UNTIL MID$(BIN$(ASC(MID$(T$,A,2))),12,1)="1"
360 CLOSE# 1
365 REM Agora todo o resultado de rastreamento está no arquivo 'DATA.DAT'
370 END