Вопрос
Можно ли скопировать файл печатной копии с жесткого диска на гибкий диск ПК, используя GPIB-команды?
Можно ли скопировать файл печатной копии с жесткого диска на гибкий диск ПК, используя GPIB-команды?
Да, это можно сделать. Ниже приводится пример на языке BASIC, который показывает, как скопировать файл печатной копии с жесткого диска прибора FSP в GPIB-контроллер.
10 REM Настройка оконечного сигнала EOI
20 IEC TERM 1
30 IEC OUT 20,"SYST:COMM:GPIB:RTER EOI"
40 REM Изменение формата печатной копии на WMF
50 IEC OUT 20,"HCOP:DEV:LANG WMF"
60 REM Изменение порта печатной копии на файл
70 IEC OUT 20,"HCOP:DEST1 'MMEM'"
80 REM Указание имени файла
90 IEC OUT 20,"MMEM:NAME 'C:\USER\DATA\FILE.WMF'"
100 REM Создание печатной копии
110 IEC OUT 20,"HCOP;*WAI"
130 REM Указание пути к жесткому диску c:
140 IEC OUT 20,"MMEM:MSIS 'C'"
150 REM Указание пути
160 IEC OUT 20,"MMEM:CDIR '\USER\DATA\'"
170 REM Размещение файла в выходном буфере
180 IEC OUT 20,"MMEM:DATA? 'FILE.WMF'"
190 REM Файл передается с заголовком. Первым символом является #.
200 REM Следующий символ указывает количество последующих символов
210 REM и размер файла без заголовка
220 REM Заголовок, например, #43210, будет удален на
230 REM следующих этапах.
240 REM Получение файла из буфера
250 IEC IN 20,S$
270 X=VAL(MID$(S$,2,1))
280 Z=VAL(MID$(S$,3,X))
290 T$=MID$(S$,X+3,Z)
300 REM Открытие файла для вывода
310 OPENO# 1,"A:\HARDCOPY.WMF"
320 REM Сохранение данных WMF в этот файл
330 PRINT# 1,T$
340 END