¿Cómo leer los datos de escaneado desde 30 MHz a 1 GHz?
Respuesta
El programa siguiente define un escaneado desde 30 MHz a 1 GHz, lo inicia y registra en un archivo todos los datos del escaneado.
10 IEC TERM 10
20 IEC TIME 5000
25 REM Los datos de escaneado se guardarán en el archivo 'DATA.DAT'
30 OPENO# 1,"DATA.DAT"
35 REM El escaneado está definido en las líneas 40 a 200
40 IEC OUT 21,"*RST;*CLS;*OPC"
50 IEC OUT 21,"INSTRUMENT RECEIVER"
60 IEC OUT 21,"SCAN:RANGES 1"
70 IEC OUT 21,"FREQUENCY:START 30MHZ"
80 IEC OUT 21,"FREQUENCY:STOP 1GHZ"
90 IEC OUT 21,"DISPLAY:TRACE:Y:TOP 100"
100 IEC OUT 21,"DISPLAY:TRACE:Y:BOTTOM -20"
110 IEC OUT 21,"SWEEP:SPACING LINEAR"
120 IEC OUT 21,"DETECTOR:RECEIVER POSITIVE,AVERAGE"
130 IEC OUT 21,"SCAN1:START 30MHZ"
140 IEC OUT 21,"SCAN1:STOP 1GHZ"
150 IEC OUT 21,"SCAN1:STEP 50KHZ"
160 IEC OUT 21,"SCAN1:BANDWIDTH:RESOLUTION 120KHZ"
170 IEC OUT 21,"SCAN1:TIME 1MS"
180 IEC OUT 21,"SCAN1:INPUT:TYPE INPUT2"
190 IEC OUT 21,"SCAN1:INPUT:ATTENUATION:AUTO ON"
200 IEC OUT 21,"SCAN1:INPUT:GAIN:AUTO ON"
203 IEC OUT 21,"DISPLAY:FORMAT SINGLE"
205 REM Hay que ajustar el formato de transferencia a real 32
210 IEC OUT 21,"FORMAT REAL,32"
220 IEC OUT 21,"*CLS"
225 REM Habilitamos la transferencia de los datos de escaneado mientras se está ejecutando el escaneado
230 IEC OUT 21,"TRACE:FEED:CONTROL ALWAYS"
235 REM El escaneado está iniciado como un escaneado único
240 IEC OUT 21,"INITIATE2:CONTINUOUS OFF;*OPC"
250 IEC OUT 21,"INITIATE2:IMMEDIATE"
260 REPEAT
270 REPEAT
275 REM El bit 9 de STATUS:OPERATION:CONDITION está ajustado cuando los datos de escaneado
276 REM están disponibles
280 IEC OUT 21,"STATUS:OPERATION:CONDITION?"
290 IEC IN 21,S$
300 UNTIL S$="512"
305 REM Obtenemos un bloque de escaneado y lo guardamos en 'DATA.DAT'
310 IEC OUT 21,"TRACE? SCAN"
320 IEC IN 21,T$
330 PRINT# 1,T$
333 REM El bloque de escaneado tiene un encabezado. El primer carácter es #. El segundo
334 REM carácter indica el número de bytes que seguirán con
335 REM información adicional, ej. 2. La información adicional indica el número
336 REM de bytes que siguen ahora con los datos de escaneado, p. ej., 32.
340 A=VAL(MID$(T$,2,1))+4
345 REM Repetimos la línea de bucle 260 hasta que el bit 12 del bloque de escaneado
346 REM (sin encabezamiento) queda ajustado.
350 UNTIL MID$(BIN$(ASC(MID$(T$,A,2))),12,1)="1"
360 CLOSE# 1
365 REM Ahora el conjunto del resultado de la traza se encuentra en el archivo 'DATA.DAT'
370 END